vCard Format Extension for JSContact
Internet-Draft draft-ietf-calext-vcard-jscontact-extensions-00
Robert Stepanek
FastMail
PO Box 234, Collins St West
Melbourne
VIC 8007
Australia
rsto@fastmailteam.com
Mario Loffredo
IIT-CNR
Via Moruzzi,1
Pisa
56124
Italy
mario.loffredo@iit.cnr.it
11 July 2022
Applications
Calendaring Extensions
addressbook
contacts
cards
VCARD
JSContact
This document defines a set of new properties for vCard and extends the use of existing ones. Their primary purpose is to align the same set of features between the JSContact and vCard formats, but the new definitions also aim to be useful within just the vCard format.
Preface
This document is a work in progress. The list of new or updated properties and parameters is likely to be incomplete. This section is removed from the document before publication.
Introduction
The JSContact [ref-jscontact] format aims to be an alternative to the vCard [RFC6350] format for representation of contact and addressbook data. As such, it introduces new semantics that are not covered in the current definition of vCard and its various extensions. Converting contact data between the two formats is defined in [ref-jscontact-vcard] with the goal of not loosing any semantics during conversion. In order to do so, this document defines a new set of properties for vCard and extends existing definitions.
Requirements Language
The key words "MUST", "MUST NOT", "REQUIRED", "SHALL", "SHALL NOT", "SHOULD", "SHOULD NOT", "RECOMMENDED", "NOT RECOMMENDED", "MAY", and "OPTIONAL" in this document are to be interpreted as described in BCP 14 [RFC2119] [RFC8174] when, and only when, they appear in all capitals, as shown here.
New Properties
CREATED Property
Property name:
CREATED
Purpose:
This property defines the date and time when the vCard was created
Value type:
A single timestamp value.
Cardinality:
*1
Property parameters:
VALUE
Description:
This is the time stamp when the vCard was created. Copying the vCard across systems does not count as a new creation, nor does a new revision. Instead, the time stamp value typically stays unchanged for the existence of the vCard.
Format definition:
This property is defined by the following notation:

created       = "CREATED" createdparam
                ":" timestamp CRLF

createdparam  = *(
                 ;
                 ; The following is OPTIONAL,
                 ; but MUST NOT occur more than once.
                 ;
                 (";" "VALUE" "=" "TIMESTAMP") /
                 ;
                 ; The following is OPTIONAL,
                 ; and MAY occur more than once.
                 ;
                 (";" any-param)
                 ;
                 )

Example(s):

CREATED:20220705093412Z
CREATED;VALUE=TIMESTAMP:20211022T140000-05

GRAMMATICAL-GENDER Property
Property name:
GRAMMATICAL-GENDER
Purpose:
This property defines the grammatical gender that shall be used to address the entity represented by this vCard.
Value type:
A single text value, restricted to an enumerated list of allowed values.
Cardinality:
*
Property parameters:
LANG
Description:
This property defines the grammatical gender that the contact prefers to be addressed by or referred at. Many human languages use grammatical genders in salutations and other language constructs. For example, the German language typically distinguishes between the gender of the recipient in both formal and informal salutations. The allowed values for this property aim to cover grammatical genders for the the majority of human languages. Future RFCs MAY define additional values if the current selection is found to be inadequate.
Format definition:
This property is defined by the following notation:

gram-gender       = "GRAMMATICAL-GENDER" gram-gender-param
                      ":" gram-gender-value CRLF

gram-gender-param =
                *(
                 ;
                 ; The following is OPTIONAL,
                 ; but MUST NOT occur more than once.
                 ;
                 (";" language-param) /
                 ;
                 ; The following is OPTIONAL,
                 ; and MAY occur more than once.
                 ;
                 (";" any-param)
                 ;
                 )

gram-gender-value = "ANIMATE" /
                    "FEMALE" /
                    "INANIMATE" /
                    "MALE" /
                    "NEUTER" /
                    x-value

Example(s):

GRAMMATICAL-GENDER:NEUTER

LOCALE Property
Property name:
LOCALE
Purpose:
This property defines the default locale that human-readable text values in this vCard should be assumed written in.
Value type:
A single text value, that MUST be a valid language-tag (see [RFC5646].
Cardinality:
*1
Property parameters:
The LANG parameter MUST NOT be assigned to this property.
Description:
Properties with value type text often contain information that is written in one of the many human languages. In order to indicate which language it was written in, implementations can assign the already-existing LANG parameter to the property. In absence of this parameter, implementations need to attempt detecting the language by text analysis. The LOCALE property allows to define a default locale in which such property values can be assumed to be written in.
Format definition:
This property is defined by the following notation:

locale       = "LOCALE" any-param
                ":" lang-tag CRLF

lang-tag     = TEXT ; MUST be a valid Language-Tag value as
                    ; specified in section 2.1 RFC5646

Example(s):

CREATED:20220705093412Z
CREATED;VALUE=TIMESTAMP:20211022T140000-05

PRONOUNS Property
Property name:
PRONOUNS
Purpose:
This property defines the gender pronouns that shall be used to refer to the entity represented by this vCard.
Value type:
A single text value.
Cardinality:
*
Property parameters:
LANG
Description:
This property contains as a free-form text the gender pronouns that the contact chooses to use for themselves. They shall be used when addressing or referring to the contact. Multiple occurrences of this property MAY define pronouns for multiple languages.
Format definition:
This property is defined by the following notation:

pronouns       = "PRONOUNS" pronouns-param
                ":" text CRLF

pronouns-param =
                *(
                 ;
                 ; The following is OPTIONAL,
                 ; but MUST NOT occur more than once.
                 ;
                 (";" language-param) /
                 ;
                 ; The following is OPTIONAL,
                 ; and MAY occur more than once.
                 ;
                 (";" any-param)
                 ;
                 )

Example(s):

PRONOUNS=they/them
PRONOUNS;LANG=de:sie
PRONOUNS:xe/xir

New Parameters
PROP-ID Parameter
Parameter name:
PROP-ID
Purpose:
This parameter identifies a property among all its siblings of the same type.
Description:
This parameter uniquely identifies a property among all of its siblings with the same name within a calendar component. A valid PROP-ID value must be of 1 and a maximum of 255 octets in size, and it MUST only contain the ASCII alphanumeric characters (A-Za-z0-9), hyphen (-), and underscore (_). The identifier only has the purpose to uniquely identify siblings, its value has no other meaning. If an application makes use of PROP-ID it SHOULD assign a unique identifier to each sibling property of the same name within their embedding component. The same identifier MAY be used for properties of a different name, and it MAY also be assigned to a same-named property that is not a sibling.
Resolving duplicate identifier conflicts is specific to the application. Similarly, handling properties where some but not all siblings have a PROP-ID is assigned, is application-specific.
Format definition:

prop-id-param  = "PROP-ID" "=" 1*255(ALPHA / DIGIT / "-"/ "_")

Example(s):

PHOTO;PROP-ID=p827:data:image/jpeg;base64,MIICajCCAdOgAwIBAg
        <...remainder of base64-encoded data...>

IANA Considerations
This section will be filled at a later stage.
Security Considerations
This section will be filled at a later stage.
References
Normative References
Informative References
[ref-jscontact]

JSContact: A JSON representation of contact data
[ref-jscontact-vcard]

JSContact: Converting from and to vCard
[RFC6350]
[RFC2119]
[RFC8174]
[RFC5646]